紅外線遙控器解碼程序

紅外線遙控是目前使用最廣泛的一種通信和遙控手段。由于紅外線遙控裝置具有體積小、功耗低、功能強、成本低等特點，因而，繼彩電、錄像機之后，在錄音機、音響設備、空凋機以及玩具等其它小型電器裝置上也紛紛采用紅外線遙控。工業(yè)設備中，在高壓、輻射、有毒氣體、粉塵等環(huán)境下，采用紅外線遙控不僅完全可靠而且能有效地隔離電氣干擾。

1 紅外遙控系統(tǒng)

通用紅外遙控系統(tǒng)由發(fā)射和接收兩大部分組成，應用編/解碼專用集成電路芯片來進行控制操作，如圖1所示。發(fā)射部分包括鍵盤矩陣、編碼調制、LED紅外發(fā)送器；接收部分包括光、電轉換放大器、解調、解碼電路。

2 遙控發(fā)射器及其編碼

遙控發(fā)射器專用芯片很多，根據(jù)編碼格式可以分成脈沖寬度調制和脈沖相位調制兩大類，這里我們以運用比較廣泛，解碼比較容易的脈沖寬度調制來加以說明，現(xiàn)以LC7461組成發(fā)射電路為例說明編碼原理。當發(fā)射器按鍵按下后，即有遙控碼發(fā)出，所按的鍵不同遙控編碼也不同。這種遙控碼具有以下特征：

采用脈寬調制的串行碼，以脈寬為0.565ms、間隔0.56ms、周期為1.125ms的組合表示二進制的“0”；以脈寬為0.565ms、間隔1.685ms、周期為2.25ms的組合表示二進制的“1”

上述“0”和“1”組成的42位二進制碼經(jīng)38kHz的載頻進行二次調制以提高發(fā)射效率，達到降低電源功耗的目的。然后再通過紅外發(fā)射二極管產(chǎn)生紅外線向空間發(fā)射，

7461產(chǎn)生的遙控編碼是連續(xù)的42位二進制碼組，其中前26位為用戶識別碼，能區(qū)別不同的紅外遙控設備，防止不同機種遙控碼互相干擾。后16位為8位的操作碼和8位的操作反碼用于核對數(shù)據(jù)是否接收準確。

當遙控器上任意一個按鍵按下超過36ms時，LC7461芯片的振蕩器使芯片激活，將發(fā)射一個特定的同步碼頭，對于接收端而言就是一個9ms的低電平,和一個4.5ms的高電平，這個同步碼頭可以使程序知道從這個同步碼頭以后可以開始接收數(shù)據(jù)。

解碼的關鍵是如何識別“0”和“1”，從位的定義我們可以發(fā)現(xiàn)“0”、“1”均以0.56ms的低電平開始，不同的是高電平的寬度不同，“0”為0.56ms,“1”為1.68ms,所以必須根據(jù)高電平的寬度區(qū)別“0”和“1”。如果從0.56ms低電平過后，開始延時，0.56ms以后，若讀到的電平為低，說明該位為“0”，反之則為“1”，為了可靠起見，延時必須比0.56ms長些，但又不能超過1.12ms,否則如果該位為“0”，讀到的已是下一位的高電平，因此取（1.12ms+0.56ms）/2=0.84ms最為可靠，一般取0.84ms左右即可。

根據(jù)紅外編碼的格式，程序應該等待9ms的起始碼和4.5ms的結果碼完成后才能讀碼。

接收器及解碼

LT0038是塑封一體化紅外線接收器，它是一種集紅外線接收、放大、整形于一體的集成電路，不需要任何外接元件，就能完成從紅外線接收到輸出與TTL電平信號兼容的所有工作，沒有紅外遙控信號時為高電平，收到紅外信號時為低電平，而體積和普通的塑封三極管大小一樣，它適合于各種紅外線遙控和紅外線數(shù)據(jù)傳輸。

下面是一個對啟點開發(fā)板配套的紅外線遙控器的解碼程序，它可以把試驗板佩戴的32鍵的紅外遙控器每一個按鍵的鍵值讀出來，并且通過實驗板上P1口的8個LED顯示出來，在解碼成功的同時并且能發(fā)出“嘀嘀嘀”的提示音。

        ORG 0000H
        AJMP MAIN     ;轉入主程序
        ORG 0003H     ;外部中斷P3.2腳INT0入口地址
        AJMP INT      ;轉入外部中斷服務子程序（解碼程序）
        ;以下為主程序進行CPU中斷方式設置
MAIN:   SETB EA       ;打開CPU總中斷請求
        SETB IT0      ;設定INT0的觸發(fā)方式為脈沖負邊沿觸發(fā)
        SETB EX0      ;打開INT0中斷請求
        ;以下對單片機的所有引腳進行初始化，全部設置成高電平
        MOV P2,#11100111B
        AJMP $
        ;以下為進入P3.2腳外部中斷子程序，也就是解碼程序
INT:    CLR EA        ;暫時關閉CPU的所有中斷請求
        MOV R6,#10
SB:     ACALL YS1     ;調用882微秒延時子程序
        JB P3.2,EXIT  ;延時882微秒后判斷P3.2腳是否出現(xiàn)高電平如果有就退出解碼程序
        DJNZ R6, SB   ;重復10次，目的是檢測在8820微秒內(nèi)如果出現(xiàn)高電平就退出解碼程序
        ;以上完成對遙控信號的9000微秒的初始低電平信號的識別。
        JNB P3.2, $   ;等待高電平避開9毫秒低電平引導脈沖
        ACALL YS2     ;延時4.74毫秒避開4.5毫秒的結果碼
        MOV R7,#26    ;忽略前26位系統(tǒng)識別碼
JJJJA:  JNB P3.2,$    ;等待地址碼第一位的高電平信號
        LCALL YS1     ;高電平開始后用882微秒的時間尺去判斷信號此時的高低電平狀態(tài)
        MOV C,P3.2    ;將P3.2引腳此時的電平狀態(tài)0或1存入C中
        JNC UUUA      ;如果為0就跳轉到UUUA
        LCALL YS3     ;檢測到高電平1的話延時1毫秒等待脈沖高電平結束
UUUA:   DJNZ R7,JJJJA
        MOV R1,#1AH   ;設定1AH為起始RAM區(qū)
        MOV R2,#2     ;接收從1AH到1BH的2個內(nèi)存,用于存放操作碼和操作反碼
PP:     MOV R3,#8     ;每組數(shù)據(jù)為8位
JJJJ:   JNB P3.2,$    ;等待地址碼第一位的高電平信號
        LCALL YS1     ;高電平開始后用882微秒的時間尺去判斷信號此時的高低電平狀態(tài)
        MOV C,P3.2    ;將P3.2引腳此時的電平狀態(tài)0或1存入C中
        JNC UUU       ;如果為0就跳轉到UUU
        LCALL YS3     ;檢測到高電平1的話延時1毫秒等待脈沖高電平結束
UUU:    MOV A,@R1     ;將R1中地址的給A
        RRC A         ;將C中的值0或1移入A中的最低位
        MOV @R1,A     ;將A中的數(shù)暫時存放在R1數(shù)值的內(nèi)存中
        DJNZ R3,JJJJ  ;接收滿8位換一個內(nèi)存
        INC R1        ;對R1中的值加1，換下一個RAM
        DJNZ R2,PP    ;接收完8位數(shù)據(jù)碼和8位數(shù)據(jù)反碼，存放在1AH/1BH中
        MOV A,1AH
        CPL A         ;對1AH取反后和1BH比較
        CJNE A,1BH,EXIT       ;如果不等表示接收數(shù)據(jù)發(fā)生錯誤,放棄
        MOV P1,1AH    ;將按鍵的鍵值通過P1口的8個LED顯示出來!
        SETB P3.5     ;蜂鳴器鳴響－嘀嘀嘀－的聲音，表示解碼成功
        LCALL YS2
        LCALL YS2
        LCALL YS2
        CLR P3.5      ;蜂鳴器停止
EXIT:   SETB EA       ;允許中斷
        RETI          ;退出解碼子程序
YS1:    MOV R4,#20    ;延時子程序1，精確延時882微秒
D1:     MOV R5,#20
        DJNZ R5,$
        DJNZ R4,D1
        RET
YS2:    MOV R4,#10    ;延時子程序2，精確延時4740微秒
D2:     MOV R5,#235
        DJNZ R5,$
        DJNZ R4,D2
        RET
YS3:    MOV R4,#2     ;延時程序3，精確延時1000微秒
D3:     MOV R5,#248
        DJNZ R5,$
        DJNZ R4,D3
        RET
        END